Atak Jednostek oraz wykonanie misji- MOD

[NaDoL]

Hi. mam kilka pytań dotyczących edytora (czytałem poprzednie działy ale nie wszystko zrozumiałem) a wiec:
1. Potrzebuje ataków co ileś tam min ( nie tylko ludzikami ale pojazdami również)
2. Jak zrobić Cele misji trochę dokładniej poproszę bo w dziale''Mój 1 mod'' nie wszystko zrozumiałem;p
3. I co wpisać żeby po zniszczeniu wszystkich wrogów (5 ich jest) pokazywały się medale i zakańczało misję??
PS: Da się ta grafikę w Menu co się wybiera Kampanie podstawić pod USA? bo każdy ma pod Rus...?
PS2: I nie pokazuje mi przy wczytywaniu tła które sobie zrobiłem, są tylko opisy.
Scieżka do mapy :
D:\Gry\Original War\mods\ViP\Missions\__AM\Am01

[NNPlaya]

1. Żeby atak odbywał się x minut po rozpoczęciu wpisz:

Code: Select all

every x$0 do
Begin
uc_side=2;  //strona konfliktu, w tym przypadku 2, czyli żóltci arabowie
uc_nation=2; //narodowość przeciwników, 1-am, 2-ar, 3-ros
hc_skills=[3,2,1,0]; //umiejętności gościa, 1 liczba - um. walki, 2- inżynierii itd.
hc_sex=1; //płeć postaci, 1 - facet, 2 - kobieta
hc_name=''; //imię postaci, tutaj losowe;
hc_class=1; //klasa postaci, 1-żołnierz, 2-inż, 3-mechanik, 4-naukowiec, 5-snajper, 8-op. moździerza, 9-bazookowiec.
identyfikator_żołnierza0=CreateHuman; //komenda stworzenia człowieka z powyższych danych.
identyfikator_żołnierza1=CreateHuman;
identyfikator_żołnierza2=CreateHuman;
uc_side=2; 
uc_nation=2;
hc_skills=[1,0,3,2];
hc_sex=1;
hc_name='';
hc_class=3;
identyfikator_mechanika0=CreateHuman;
identyfikator_mechanika1=CreateHuman;
identyfikator_mechanika2=CreateHuman;
vc_chassis=ar_light_trike;  //typ podwozia, tutaj arabski lekki trzykołowiec
vc_engine=engine_combustion;  //typ silnika, tutaj spalinowy
vc_control=control_manual;  //typ sterowania, tutaj ręczne
vc_weapon=ar_light_gun; //broń, tutaj lekkie działo
identyfikator_pojazdu0=CreateVehicle; //komenda stworzenia pojazdu z powyższych danych
identyfikator_pojazdu1=CreateVehicle;
identyfikator_pojazdu2=CreateVehicle;
PlaceHumanInUnit(identyfikator_mechanika0,identyfikator_pojazdu0); //komenda umieszczająca człowieka w pojeździe
PlaceHumanInUnit(identyfikator_mechanika1,identyfikator_pojazdu1); 
PlaceHumanInUnit(identyfikator_mechanika2,identyfikator_pojazdu2); 
PlaceUnitArea(nazwa_jednostki,nazwa_arei_gdzie_pojawią_się_wrogowie,false); //false oznacza, że wrogowi nie bedą się materializować, trzeba to pisać dla każdej jednostki, ale nie dla kierowców, tylko dla ich pojazdów
ComAttackUnit([atakujący_wrogowie],jakaś_jednostka); //atakujący wrogowie to wszystkie atakujące jednostki w kwadratowym nawiasie oddzieleni przcinkami 
end;

2: Zajrzyj do "editing manual" w menu start Original War. Tam jest to ładnie objaśnione
3: Z medalami jak wyżej, a co do wrogów (masz na myśli pojedyncze jednostki, tak?) to zrób coś takiego:

Code: Select all

every 0$1 trigger IsDead(wróg1) and IsDead(wróg2) and IsDead(wróg3) and IsDead(wróg4) and IsDead(wróg5) do
Begin
GiveMedals('Main'); //danie medali, zajrzyj do "editing manual"
RewardPeople(FilterAllUnits([[f_alive,],[f_side,1],[f_type,unit_human]]); //Przydzielanie doświadczenia 
YouWin; //Wygrałeś  :D 
end;

PS2: Plik powinien być w [rozdzielczość_ekranu] w katalogu LoadImgs w folderze Interface i mieć nazwę xxyy, gdzie xx to strona konfliktu (am, ar, ru) yy to numer misji (01, 02, 03...)

[Radzio]

twoje tlo nie bedzie pasowalo do kazdego modu
lepiej uzyj tego obrazka: KLIK
i umiesc go w [katalog_modu]/Interface/Alien/Edit/

[NNPlaya]

Nie nie będzie pasować do każdego, tylko jest kompatybilne wyłącznie z moim modem. Sorry za pomyłkę

[Radzio]

w ramach scislosci to kazdy kto wejdzie na te forum moze stosowac to moje tlo bez ograniczen, nie wolno mu jedynie zastrzegac sobie praw do niego gdyz jest ono dobrem wspolnym

[NaDoL]

"editing manual" <- tego to ja nie mam lol w menu satart/ow to mam tylko konfigurator, czytaj to i usuniecie gry...dlatego wlasnie pytam, a co do obrazka to mi nie chodzi o to z wyborem kampani tylko ten co jest jak sie wczytuje misja tam gdzie pisze Syberia 1 luty 2006 etc a z tym przy wyborze to pytałem czy da sie podmienic Amerykanski znaczek (bo jak kopjuje plik txt. z czyjegos moda to mi sie zacina jak wciskam ;p)
I mam prośbę, jak powinien wyglądać kod cały, aby po 25 min baze zaatakowało 5 ruskich ludzi 4lvl 2 bazoki i 5 hg ruskich na rope np. ?? i te medale razem z zakończenie misji są najważniejsze z deka;p ( konkretnie to 2 medale za pokonanie wrogów i 1 za to że przezył bolek i lolek) i tu też mam pytanie jakby wyglądał taki kod, że sie te cele wyświetlą na poczatku a na końcu beda te medale i zakończenie misji po rozwaleniu każdej wrogiej jednostki?[Dopiero zaczynam edytor wiec może trochę lamie xd]
PS: jeszcze takie małe pytanie da sie przywrócić fog of war, jak przy teting mode troche odkryłem, a chce to zamazac??

[Radzio]

aby zamazac to cos muisz uzyc komendy

Code: Select all

ResetFog;

[NNPlaya]

Code: Select all

export soldat1,soldat2,soldat3,soldat4,soldat5,soldat6,soldat7,mechanik1,mechanik2,mechanik3,mechanik4,mechanik5,hg1,hg2,hg3,hg4,hg5;

Starting 
Begin
ResetFog;
end;

every 25$0 do
Begin
uc_side=3;
uc_nation=nation_russian;
hc_skills=[4,0,1,0];
soldat1=CreateHuman;
soldat2=CreateHuman;
soldat3=CreateHuman;
soldat4=CreateHuman;
soldat5=CreateHuman;
hc_class=9;
soldat6=CreateHuman;
soldat7=CreateHuman;
hc_skills=[1,0,4,0];
hc_class=3;
mechanik1=CreateHuman;
mechanik2=CreateHuman;
mechanik3=CreateHuman;
mechanik4=CreateHuman;
mechanik5=CreateHuman;
vc_chassis=ru_heavy_tracked; 
vc_engine=engine_combustion; 
vc_control=control_manual; 
vc_weapon=ru_heavy_gun;
hg1=CreateVehicle;
hg2=CreateVehicle;
hg3=CreateVehicle;
hg4=CreateVehicle;
hg5=CreateVehicle;
PlaceHumanInUnit(mechanik1,hg1);
PlaceHumanInUnit(mechanik2,hg2);
PlaceHumanInUnit(mechanik3,hg3);
PlaceHumanInUnit(mechanik4,hg4);
PlaceHumanInUnit(mechanik5,hg5);
PlaceUnitArea(soldat1,nazwa_arei,false);
PlaceUnitArea(soldat2,nazwa_arei,false);
PlaceUnitArea(soldat3,nazwa_arei,false);
PlaceUnitArea(soldat4,nazwa_arei,false);
PlaceUnitArea(soldat5,nazwa_arei,false);
PlaceUnitArea(soldat6,nazwa_arei,false);
PlaceUnitArea(soldat7,nazwa_arei,false);
PlaceUnitArea(hg1,nazwa_arei,false);
PlaceUnitArea(hg2,nazwa_arei,false);
PlaceUnitArea(hg3,nazwa_arei,false);
PlaceUnitArea(hg4,nazwa_arei,false);
PlaceUnitArea(hg5,nazwa_arei,false);
ComAttackUnit([soldat1,soldat2,soldat3,soldat4,soldat5,soldat6,soldat7,hg1,hg2,hg3,hg4,hg5],FilterAllUnits([f_side,1]));
end;

UWAGA: Zakładam, że dowodzisz ciemnoniebieskimi Amerykańcami.

[NaDoL]

Ta, dobrze zakładasz xD
Z tym że te odziały jada mi na srodek mapy a nie do bazy, to chyba dlatego że podczas tetsów 1 jednostke własnie tam ustawiłem, da się to zmienić??
I kod na te medaliki i cele;p?? troche męcze ale najlepiej uczę się na gotowych kodach później ewentualnie podmieniając wartości

[NNPlaya]

To zamiast ComAttackUnit wpisz

Code: Select all

AddComMoveToArea([soldat1,soldat2,soldat3,soldat4,soldat5,soldat6,soldat7,hg1,hg2,hg3,hg4,hg5],teren_bazy);
AddComAttackUnit([soldat1,soldat2,soldat3,soldat4,soldat5,soldat6,soldat7,hg1,hg2,hg3,hg4,hg5],FilterAllUnits([f_side,1]));

Oczywiście na terenie bazy stwórz areę o nazwie "teren_bazy" lub inną

Cele misji:

Żeby dodawać cele misji wpisz najpierw w texts.txt albo pliku wri (do użycia przez grę)

Code: Select all

# CEL1 //to jest nazwa robocza do użycia w Sailu
Add Main niedajsiezabic //"niedajsiezabic" to nazwa robocza do użycia w texts.txt/pliku wri
- Treść celu misji
#

# CEL1W
Out niedajsiezabic
#

Potem w Sailu:

Code: Select all

ChangeMissionObjectives('CEL1');

żeby ustawić cel i

Code: Select all

ChangeMissionObjectives('CEL1W');

żeby przekreślić cel (oznaczyć jako wykonany)

Medale:

Najpierw w texts.txt/pliku wri

Code: Select all

^ MAIN //to jest skrót do dania medali
Target achieved

Teraz konkretne medale:

Code: Select all

* bolekilolek
+ Bolkowi i Lolkowi nic się nie stało.
*

* obrona
+ Obroniłeś bazę.
*

* straty
+ Nie poniosłeś strat.
- Straciłeś kilku ludzi.
*

Potem w Sailu żeby dodać medal :

Code: Select all

AddMedal('bolekilolek',1); //1 znaczy, że dostaniesz medal
AddMedal('obrona',1);
AddMedal('straty',-1); //-1 oznacza, że nie dostaniesz medalu

i na końcu gdy chcesz, żeby medale się wyświetliły (poprzednie komendy to dodawanie ich w pamięci)

Code: Select all

GiveMedals('MAIN');

Kurde... Więcej razy innym ludziom nie będę tego tłumaczył

[NaDoL]

hhe spoko, a te plik .txt lub .wri to gdzie stworzyć? i jakbys mial chwile to jeszcze możesz mi dialogi przekopjwoac jak powinno byc:P
I w ogóle to nie obczajam;p tj są jakieś błędy, czy mógł byś napisać fragment kodu? jeśli:
Chce dialog na początku misji zaraz po zaczęciu-
*ViP*Nadol - witoj jawor
*ViP*Jawor - witoj nadol
I jak chce aby misja kończyłą się po zabiciu wszystkich jendostek medalami(lub jak zginie *ViP*Nadol lub *ViP*Jawor lub wszyscy ludzie to przegrana?):
Dowódcy żyją
Przejąłeś kontrole nad terenem
+male straty własne
-brak strat
i Cele na początku:
-bolek i lolek musza przezyć
-przejmij kontrole nad calym terenem
i jak by wglądał taki kod (w nowym module)
PS: jak gra sprawdza że np. w celu i medalu jest ze musisz zabic wszystkich i jak to zrobisz to pokazuje medale?

[NNPlaya]

plik texts.txt tworzysz w folderze mapy, a wri w [katalog_modu]/Campaigns/Am/Txt01.wri (01 dla pierwszej misji of coz)

Najpierw w texts.txt/wri dodajesz teksty dialogów:

Code: Select all

$ nadi1
- witoj jawor

$ jawor1  //jawor1 to jest skrót używany w Sailu; identyfikator dialogu inaczej
- witoj nadol 

Po ostatnim tekście dialogu musi być odstęp 1 linijki!

Potem w Sailu:

Code: Select all

Starting
Begin
Say(Nadol,'nadi1');
Say(Jawor,'jawor1');
end;

Żeby misja kończyła się przegraną musisz dodać w texts.txt:

Code: Select all

| nadiisded
Nadi pożegnał się ze światem.

| jaworisded
Jawor zarobił kilka kulek w łeb.

Potem w Sailu:

Code: Select all

every 0$1 trigger IsDead(Nadol) do
Begin
YouLost('nadolisded');
end;

every 0$1 trigger IsDead(Jawor) do
Begin
YouLost('jaworisded');
end;

Cele:
W texts.txt/wri:

Code: Select all

# CEL1
Add Main dowodcy
- Bolek i Lolek muszą przeżyć
#

# CEL2
Add Main kontrola
- Przejmij kontrolę nad całym terenem
#

# CEL3
Add Secondary straty
- Wystrzegaj się strat własnych
#

Wygrana i medale (Przyjmuję, że po zabiciu wszystkich rusków na mapie). W Sailu:

Code: Select all

every 0$1 trigger IsDead(Ruscy) and IsDead(Ruscy2) do
Begin
AddMedal('MED1',1);
AddMedal('MED2',1);
If FilterAllUnits([[f_side,1],[f_type,unit_human],])<10 then //zamiast 10 wstaw liczbę wszystkich swoich ludzi łącznie z dowódcami
Begin
AddMedal('MED3,-1);
end 
else
Begin
AddMedal('MED3',1);
end;
GiveMedals('MAIN');
RewardPeople(FilterAllUnits([[f_side,1],[f_type,unit_human],[f_alive]]));
YouWin;
end;

Potem w texts.txt/wri:

Code: Select all

^ MAIN
Target achieved

* MED1
+ Dowódcy żyją
*

* MED2
+ Przejąłeś kontrolę nad obszarem
*

* MED3
+ Żadnych strat
- Małe straty
*

W rezultacie CAŁY kod wyglądałby tak (SAIL):

Code: Select all

export soldat1,soldat2,soldat3,soldat4,soldat5,soldat6,soldat7,mechanik1,mechanik2,mechanik3,mechanik4,mechanik5,hg1,hg2,hg3,hg4,hg5, Ruscy, Ruscy2;

Starting
Begin
ResetFog;
Ruscy=FilterAllUnits([[f_side,3],[f_type,unit_human]]);
Wait(0$2);
CenterNowOnUnits([Nadol,Jawor]); //centruje widok na Nadolu i Jaworze
InGameOn;  //włącza efekt scenki
Say(Nadol,'nadi1');
Say(Jawor,'jawor1'); 
InGameOff;  //wyłącza efekt scenki
end;

every 25$0 do
Begin
uc_side=3;
uc_nation=nation_russian;
hc_skills=[4,0,1,0];
soldat1=CreateHuman;
soldat2=CreateHuman;
soldat3=CreateHuman;
soldat4=CreateHuman;
soldat5=CreateHuman;
hc_class=9;
soldat6=CreateHuman;
soldat7=CreateHuman;
hc_skills=[1,0,4,0];
hc_class=3;
mechanik1=CreateHuman;
mechanik2=CreateHuman;
mechanik3=CreateHuman;
mechanik4=CreateHuman;
mechanik5=CreateHuman;
vc_chassis=ru_heavy_tracked;
vc_engine=engine_combustion;
vc_control=control_manual;
vc_weapon=ru_heavy_gun;
hg1=CreateVehicle;
hg2=CreateVehicle;
hg3=CreateVehicle;
hg4=CreateVehicle;
hg5=CreateVehicle;
PlaceHumanInUnit(mechanik1,hg1);
PlaceHumanInUnit(mechanik2,hg2);
PlaceHumanInUnit(mechanik3,hg3);
PlaceHumanInUnit(mechanik4,hg4);
PlaceHumanInUnit(mechanik5,hg5);
PlaceUnitArea(soldat1,nazwa_arei,false);
PlaceUnitArea(soldat2,nazwa_arei,false);
PlaceUnitArea(soldat3,nazwa_arei,false);
PlaceUnitArea(soldat4,nazwa_arei,false);
PlaceUnitArea(soldat5,nazwa_arei,false);
PlaceUnitArea(soldat6,nazwa_arei,false);
PlaceUnitArea(soldat7,nazwa_arei,false);
PlaceUnitArea(hg1,nazwa_arei,false);
PlaceUnitArea(hg2,nazwa_arei,false);
PlaceUnitArea(hg3,nazwa_arei,false);
PlaceUnitArea(hg4,nazwa_arei,false);
PlaceUnitArea(hg5,nazwa_arei,false);
AddComMoveToArea([soldat1,soldat2,soldat3,soldat4,soldat5,soldat6,soldat7,hg1,hg2,hg3,hg4,hg5],teren_bazy);
AddComAttackUnit([soldat1,soldat2,soldat3,soldat4,soldat5,soldat6,soldat7,hg1,hg2,hg3,hg4,hg5],FilterAllUnits([f_side,1]));
Ruscy2=[soldat1,soldat2,soldat3,soldat4,soldat5,soldat6,soldat7,mechanik1,mechanik2,mechanik3,mechanik4,mechanik5,hg1,hg2,hg3,hg4,hg5];
end;

every 0$1 trigger IsDead(Nadol) do
Begin
YouLost('nadolisded');
end;

every 0$1 trigger IsDead(Jawor) do
Begin
YouLost('jaworisded');
end;

every 0$1 trigger IsDead(Ruscy) and IsDead(Ruscy2) do
Begin
AddMedal('MED1',1);
AddMedal('MED2',1);
If FilterAllUnits([[f_side,1],[f_type,unit_human],])<10 then //zamiast 10 wstaw liczbę wszystkich swoich ludzi łącznie z dowódcami
Begin
AddMedal('MED3,-1);
end 
else
Begin
AddMedal('MED3',1);
end;
GiveMedals('MAIN');
RewardPeople(FilterAllUnits([[f_side,1],[f_type,unit_human],[f_alive]]));
YouWin;
end;

[NaDoL]

Hmm no ok coraz jaśniej tylko że wyświetla error przy linijce:
CenterNowOnUnits([Nadol,Jawor]); <= ze coś ''nadol''
i:
Ruscy=FilterAllUnits([[f_side,3],[f_type,unit_human]]); <= ze cos ''ruscy''
oto kod, bo ja mam kilka modulów, kilka atakow w odzielnych i skrzynie medale w odzielnych oto one:
1 Modul:

Starting
Begin
ResetFog;
Ruscy=FilterAllUnits([[f_side,3],[f_type,unit_human]]);
Wait(0$2);
CenterNowOnUnits([Nadol,Jawor]);
InGameOn;
Say(Nadol,'nadi1');
Say(Jawor,'jawor1');
InGameOff;
end;

<= Jeszcze skrzynki chcial bym tu dac zeby co 30 sek po 4 spadaly.
TU posrodku są ataki (dzialaja bo spr;p) i:
2 Modul

every 0$1 trigger IsDead(Nadol) do
Begin
YouLost('nadolisded');
end;

every 0$1 trigger IsDead(Jawor) do
Begin
YouLost('jaworisded');
end;

every 0$1 trigger IsDead(Ruscy) and IsDead(Ruscy2) do
Begin
AddMedal('MED1',1);
AddMedal('MED2',1);
If FilterAllUnits([[f_side,1],[f_type,unit_human],])<15 then
Begin
AddMedal('MED3,-1);
end
else
Begin
AddMedal(MED3',1);
end;
GiveMedals('MAIN');
RewardPeople(FilterAllUnits([[f_side,1],[f_type,unit_human],[f_alive]]));
YouWin;
end;

PS: Jak zrobić zeby w misji wyswietlało mi twarz kolesia tą co zrobiłem w edytorze??

[NNPlaya]

Skrzynie:

Code: Select all

every 0$30 do
Begin
enable;
CreateCratesAnywhere(4,true);
end;

Problem, że wyświetla "Nadol coś tam" to "undefinied integer value??? Jeśli tak to kliknij na postać Nadola i w okienku, gdzie należy wpisać indentyfikator wpisz po prostu Nadol (albo nadol, NADOL czy też NaDoL, wielkość liter nie ma znaczenia), a co do "Ruscy" jeśli wyświetla się ten sam komunikat to wpisz export Ruscy w pierwszym module.

Twarz: Zapisz (twarz lub kilka twarzy) XichtED`em w formacie galerii i umieść w katalogu modu w folderze "Gallery". Następnie stwórz w "Gallery" plik txt o nazwie Gallerys i wpisz w nim nazwę pliku galerii (bez rozszerzenia .xgl) i naciśnij enter. Zapisz.

[NaDoL]

Hi. Jak wcześniej wspomniałęm zaczełem robić moda, i mam mały problem:
Co wpisac w sailu jeśli chce aby wyświetlił się dialog jeśli Jawor lub Pamel lub Nadol bedzie w Area01 ?? chodzi mi o sam fragment ''Nadol lub Pamel lub Jawor'' bo pojedyńczo to wiem...i tak samo z savecharacters żeby mi wyświetlało kilku w jednym oknie, a nie każdy w odzielnym...
I jak mam komende że po czymś tam postacie ida do budynku to jak wyłączyć sterowanie?? tj żeby nie można było zmienić im komendy ktora dostali od ''pana Sail'a''? da sie?